Counting in Binary

A good starting point is to see how your micro counts. A computer can only tell if something inside it is on or off. Think of it like a light bulb. If it's ON we can call that ONE. If it's OFF we can call that ZERO.

Suppose we have two light bulbs. How many different patterns of ON and OFF can we have?

		both OFF
		right ON
		left ON
		both ON

Making number 1 stand for ON and number 0 stand for OFF we can turn this into a system for counting.

So we can only count up to three with two bulbs. With three light bulbs we can count to seven. We call this BINARY counting. Just like a bicycle has TWO wheels and binoculars have TWO lenses, binary counting uses only TWO numbers. So you can only count with 0 and 1.

People are used to counting using TEN numbers: 0,1,2,3,4,5,6,7,8,9. The word for counting with TEN numbers is DECimal from the Latin decem meaning ten.

In binary counting, each digit is known as a BIT (short for BINARY DIGIT). The binary number 101 is a three BIT number.

Let's try converting some binary numbers to decimal numbers.

Suppose we have a binary number with four bits, say 1010.

We can set it out like this:

Notice that each column heading is two times more than the one to its right. To convert 1010 to decimal we just read off the columns where there's a 1 and add the decimal values together. Like this:

Using these columns, what's the largest four bit number we can make?

Yes, it's 1111:

What is this in decimal? Add up the columns and see!

The table below shows all the possible binary numbers using four bits, ie the equivalent of 0 to 15.

We can of course start with a decimal number and convert it to binary.

Here's a program to help you. This program will change decimal numbers (up to 15) to the equivalent four bit binary numbers.

  10 CLEAR
  15  REM Print information 4 lines down.
  20 PRINT AT 4,0;"This program will change a"
  30 PRINT "decimal number between 0 and 15"
  40 PRINT "to its binary equivalent."
  45  REM Leave a line
  50 PRINT
  60 PRINT "Type in a decimal number between"
  61 PRINT "0 and 15 and press ENTER"
  65  REM Number to be decoded is input and
     stored in N.
  70 INPUT "Decimal number 0-15: ";N
  80 IF N<0 OR N>15 THEN GO TO 10
  90 LET D=0: IF N>7 THEN LET D=1
 100 LET M=N: IF D=1 THEN LET M=N-8
 110 LET C=0: IF M>3 THEN LET C=1
 120 LET P=M: IF C=1 THEN LET P=M-4
 130 LET B=0: IF P>1 THEN LET B=1
 140 LET Q=P: IF B=1 THEN LET Q=P-2
 150 LET A=0: IF Q>0 THEN LET A=1
 155  REM Print headings.
 160 PRINT AT 13,6;"DECIMAL"
 170 PRINT AT 13,17;"BINARY"
 175  REM Print decimal number.
 180 PRINT AT 15,9;N
 185  REM Print BITs of binary equivalent.
 190 PRINT AT 15,18;D;C;B;A
 200 PRINT AT 20,0;
 201 PRINT "Do you wish to check another"
 210 PRINT "number? (Y/N)"
 215  REM Next letter or number pressed is
     stored in INKEY$ if pressed within 40
     seconds.
 220 PAUSE 2000
 225  REM If you press y or Y you can try a
     new number. If not program will end
     having printed goodbye.
 230 IF INKEY$="Y" OR INKEY$="y" THEN GO TO 10
 240 CLS : PRINT AT 5,5;"GOODBYE"
 250 STOP

So you can see that by using 0 and 1 a computer can count in binary

What's the biggest number your computer can store and handle? Most home computers today are 8 bit; they count as though they have sets of eight light bulbs to turn ON and OFF inside. Using sets of eight bits, computers can handle whole numbers as large as two thousand million (2,000,000,000).

Of course, the computer doesn't use light bulbs. Remember, the parts that go on and off are called BITS. You may have heard people talk about 8 bit, 16 bit and even 32 bit micro computers. The micro computer that you use at present is probably an 8 bit machine. Eight bits are often known as a BYTE.

Later in the book we shall want to know the decimal equivalent of a BYTE so let's try a few examples here.

Consider the number 11111111.

Now try another.

Now you work out 10001000.

Yes! The answer is 136.

Working out 8 bit numbers is quite difficult so computer people sometimes use a special code called HEXADECIMAL.

Counting in hexadecimal

Have you noticed that some of the numbers in the ZX Spectrum BASIC programming manual are followed by the letter h?

In some books and articles, such as those about machine code for the Z80 microprocessor, this type of number might start with the symbol $ or begin with the code 0x.

These numbers are a compact form that is more compatible with the way the computer counts in binary.

When we count we use ten single digits (decimal):—

Each number is one digit, six is 6 and three is 3.

What happens when we reach ten?

When we get to ten we haven't got any more single digits. We convert our ten units to a single TEN and no UNITS and use two digits.

We can think of the computer counting in sets of four bits. We saw that with four bits we can count from 0 to 15 (16 numbers.)

The code used to count in groups of sixteen numbers is called HEXADECIMAL. (Remember, a HEXagon has SIX sides, so hexadecimal is 6+10 or 16.)

0  1  2  3  4  5  6  7  8  9... What's next?

(No one has yet invented single digit numerals beyond 9.)

What computer people have done is to use letters to represent the rest of the counting in hexadecimal. So, counting in hex (short for hexadecimal) looks like this...

0  1  2  3  4  5  6  7  8  9  A  B  C  D  E  F

In the hex code, F stands for 15 and A for 10. What does C stand for?

We can now look at three ways of counting.

Binary is used by the computer in all its workings.

Hexadecimal is the name of the code used for counting using sixteen digits.

Decimal is the way we are used to counting in everyday life and it uses ten single digits.

Don't forget that ZERO is a number too!

The ZX Spectrum can accurately represent whole numbers (called integers) up to 4,294,967,295. That is

11111111111111111111111111111111

in binary or FFFFFFFFh in hex.

When we see a number followed by 'h' we know it is a hexadecimal number.

This explains the mystery of the 'funny' numbers!

Most computers accept numbers in decimal or in hexadecimal and then convert them into binary. It's easier for people to work in decimal rather than hexadecimal, so let's see the computer change numbers from hex to decimal and back again.

Use the following program to convert from hex to decimal.

  10 LET D=0: INPUT "Hex (Q to Stop): ";H$
  20 LET X=LEN H$: IF X<1 THEN GO TO 10
  30 LET H=CODE H$: LET H$=H$(2 TO )
  40 IF X>0 THEN LET D=D*16
  50 IF H>96 THEN LET H=H-32
  60 IF H=81 THEN STOP
  70 IF H>64 AND H<71 THEN LET D=D+H-55
  80 IF H>47 AND H<58 THEN LET D=D+H-48
  90 IF X=1 THEN PRINT D
 100 GO TO 20

Run the program. Type in:

F and press ENTER *

You should get 15.

​* After typing in any instructions the ENTER key should of course be pressed. This symbol will remind you.

ENTER

Try another one,

FF Enter

Did the number 255 appear on the screen?

So you can see it is very easy to translate from hexadecimal to decimal, using your computer.

If you want to go the other way (to find the hexadecimal equivalent of a decimal number) then you can use this program.

10 LET H$="": INPUT "Decimal (-1 to Stop): ";D
20 IF D=-1 THEN STOP
30 IF D<0 THEN GO TO 10
40 LET R=D-INT (D/16)*16: LET D=INT (D/16)
50 LET H$=CHR$ (R+48+(R>9)*7)+H$
60 IF D>0 THEN GO TO 40
70 PRINT H$: GO TO 10

Run the program.

Type in: 15 Enter

The answer should be F.

Try: 10 Enter

and: 17 Enter

This will give you the hex equivalent of decimal 10 and decimal 17.

Now we can count in binary like a computer. We are able to change a binary number into a hexadecimal number and then back again.

ASCII code

How does the computer, only being able to work in 0s and 1s, represent letters of the alphabet and other symbols on your keyboard?

There is a code which allows it to do

this and it is very important for computers.

If computers are ever going to talk to each other they need to use the same code. The usual code is called an ASCII code. ASCII, pronounced 'askey', stands for American Standard Code for Information Interchange.

There is a copy of
the ASCII code in your BASIC manual, or you can use your computer to find it!

Here's how...

If you type

PRINT CODE "A" Enter

it will give you the code for the letter A in decimal.

The computer remembers this as the binary number equal to 65 decimal and hex 41.

That is...

0100 0001

(There is a small space between the two sets of four bits to make it easier to read.)

If you read this binary number as two four bit numbers you will see how we get hex 41. (Look back at page 7.)

0100 0001 4 1

So the hexadecimal value of
0100 0001 is 41.

Let's try another one.

PRINT CODE "G" Enter

The computer will respond with 71.

G is decimal 71, hex 47 and binary 0100 0111.

That is...

Binary 0100 0111 4 7 47h

Remember the letter
'h' after a number is a way of reminding us this is a hexadecimal number

We can use the computer to convert from binary to a character like this:

PRINT CHR$ BIN 0100 1011

Enter

The result will be K.

Binary 0100 1011 4 B 4Bh

So 0100 1011 is the same as hex 4B.

We can check this by looking up hex 4B in the ASCII Code table. (See page 10.)

Memory

In order for a computer to work, it must have memory. It is no use giving the computer two numbers to add together if it forgets the first number before you give it the second.

Shown below is a photograph of the inside of a Sinclair ZX Spectrum 16K microcomputer (Issue 1). There are two

A chip

main areas of memory which are each made up of integrated circuits (ICs) often known as chips.

The ICs are known as chips because inside the black plastic case is a little chip of silicon containing the memory circuits.

We are going to look at three types of memory: ROM, RAM and EPROM.

In this special letter rack, only one envelope can be stored in a location (pigeon hole) at any one time.

If you like, you can have a look at what is stored in one of the locations in a ROM.

Type in:

PRINT PEEK 5440 Enter

A number will appear on the screen, probably 83. If you are using a later machine, manufactured by Amstrad, the number will probably be 65. This is what is stored in location 5440 in the computer. The number 5440 is one of the ROM addresses.

All locations between 0 and 16383 are in ROM, so you can look at any of them using the same command.

We can look to see if there is anything stored in RAM at an address, say 28000.

Type in:

PRINT PEEK 28000 Enter

It will be zero unless you have run a program.

Having read this location and found the number zero, let's replace it with your age.

Suppose you are 12 years old.

Type in:

POKE 28000,12 Enter

This puts 12 in location 28000. Let's see if it's there.

Type in:

PRINT PEEK 28000 Enter

Did the computer print your age?

If you try to put in a number greater than 255 it will not work correctly because 255 is the maximum number you can store in an 8 bit memory location. Remember 1111 1111 would be all bits ON and this is 255 decimal.

Try using the age of somebody older than you and put that in location 28000. You can keep doing this. The value stored

in a RAM location can be changed over and over again.

The disadvantage of RAM is that if we switch off the computer we lose all the information stored in this type of memory. Computer people say, therefore, that RAM is volatile memory — the contents can vanish. That's why you need to save your programs on cassette or disc from RAM so that they won't be lost when the electrical supply is turned off. When you want to use a program again you load it from the tape or disc into the RAM part of the computer's memory.

Switch off your microcomputer and then turn it on again. Look at what is now in the memory at address 15000 in ROM and address 28000 in RAM.

Type in:

PRINT PEEK 15000 Enter

Is this still the previous value, 255 (or 33 for 128K), in the ROM section?

PRINT PEEK 28000 Enter

Is this 0 in the location 28000 in RAM?

How can we find out which locations are in RAM and which in ROM? K stands for kilobyte.
In computers, this is 1024 bytes.

We can use a map!

It's in the Spectrum BASIC programming manual if you know how to use it.

A computer memory map is unusual. You can think of it as all the memory locations stacked one above the other like an enormous stack of single pigeon holes.

To find our way about the memory we use this special map.

The ZX Spectrum can directly address locations from 0 up to 65535 (FFFFh). These can't all be drawn individually on a page so in the map we just give the addresses which interest us like the top, the bottom and those that divide sections of memory.

You can now see the ROM area, the RAM area and the position of those locations we have already looked at such as 15000 and 28000.

AND

Let's consider two bulbs A and B. A is a red bulb and B is a green bulb. As on page2 if a bulb is ON we will say it is in logic state 1 and if OFF, logic state 0.

The drawing below shows all the possible combinations of ONs and OFFs for the two bulbs.

We can now look at each combination and see in which column the red lamp and the green lamp are ON.

If they are both on we put a 1 in the AND row, if not then we put a 0 as shown above.

Now consider two numbers in binary, such as 2 and 3.

If we AND the right bit of each number we get 0 AND 1 which gives 0. If we AND the left bits we get 1 AND 1 which gives 1 as shown above.

Now binary 10 is decimal 2 so if we AND 2 and 3 we get 2.

Use this program to check the result.

 10 REM AND, OR, EOR (using Z80 machine code)
 20 LET H$="DD2A0B5CDD7E04DD460CA006004FC9"
 30 DEF FN A(a,b)=USR USR "A"
 40 LET A=USR "A": GO SUB 180
 50 LET H$(21)="B"
 60 DEF FN O(a,b)=USR USR "O"
 70 LET A=USR "O": GO SUB 180
 80 LET H$(21)="A": LET H$(22)="8"
 90 DEF FN E(a,b)=USR USR "E"
100 LET A=USR "E": GO SUB 180
110 INPUT "A (-1 to END): ";A: IF A<0 THEN STOP
120 INPUT "B: ";B
130 PRINT A;" AND ";B;" = ";FN A(A,B)
140 PRINT A;" OR  ";B;" = ";FN O(A,B)
150 PRINT A;" EOR ";B;" = ";FN E(A,B)
160 PRINT : GO TO 110
170 DEF FN B(x)=x-48-7*(x>57)-32*(x>70)
180 FOR I=2 TO LEN H$ STEP 2 : LET L=CODE H$(I)
190 POKE A,FN B(CODE H$(I-1))*16+FN B(L)
200 LET A=A+1: NEXT I : RETURN

; Bitwise Operation Machine Code
; Z80 Resources: Assembler, Disassembler, Reference

init:               ; Get parameters from DEF FN X(x,y)
    ld ix,(23563)   ; See: Sinclair User 45, pp. 62-64
    ld a,(ix+4)     ; Lower byte of x into register a
    ld b,(ix+12)    ; Lower byte of y into register b
inst:               ; Replacement location
    and b           ;   AND (default)
    ld b,0          ; Put 0 in register b (high byte)
    ld c,a          ; Put result in register c (low byte)
    ret             ; return

; End of routine (15 bytes)

; Operations for replacement at location inst
AND:
    and b           ; for FN A(a,b) in UDG A+B (default)
OR:
    or b            ; for FN O(a,b) in UDG O+P
EOR:
    xor b           ; for FN E(a,b) in UDG E+F

Type in the program and run it.

RUN Enter

Try 2 and 3.

Did you get 2?
You now know why!

OR

Let's now look at the OR function. Consider the red and green bulbs on the opposite page. This time we will consider under which conditions the red OR the green bulb is ON.

Note that OR in this case is not quite the same as 'or' as used in normal English. If the red bulb is ON or the green bulb is ON we put a 1 in the OR column.

So logical OR is true if either or both lights are ON.

An example of the OR condition occurs in most cars. The interior light of a car comes on if just the front offside door or just the front nearside door are open or both front doors are open.

Let us now OR two numbers bit by bit. We can use 2 and 3.

If we OR the right bit of each number we get 0 OR 1 = 1. The left bits give 1 OR 1 = 1.

So if we OR 2 and 3 we get 3.

You can now try 3 bit numbers. What is 5 OR 3?

We get:

Check your answer using the program. Do you get 5 OR 3 equals 7?

EOR

EOR stands for Exclusive OR, sometimes abbreviated XOR. The Exclusive OR (EOR) behaves in the same way as 'or' in the English language.

Consider the bulbs on page 30 again.

We put a 1 in the EOR column only when either the red bulb or the green bulb is ON.

Let us now EOR two numbers bit by bit. We can use the same two numbers as before, 2 and 3.

If we EOR the right bit of each number we get 0 EOR 1 = 1. The next left bits give 1 EOR 1 = 0.

So 2 EOR 3 equals 1.

Try this on your computer.

Do you now
understand the meaning of the logic terms AND, OR and EXCLUSIVE OR?

If you don't, practise some more and check them using your computer.

You will find these terms used in digital electronics, as well as colour graphics.